type
   TEffect = class
   public
      procedure BlackOut(img : TImage);
      procedure BlackIn(img : TImage; backbmp : TBitmap);
            
            
      procedure MosaicOut(img : TImage);
      procedure MosaicIn(img : TImage; backbmp : TBitmap);
            
            
   end;
            

            
//背景のモザイクアウト
procedure TEffect.MosaicOut(img : TImage);
var
   //引数imgの幅
   img_w : Integer;
   //塗りつぶすブロックの幅および高さ
   rect_w,rect_h : Integer;
   //塗りつぶすブロックの縦または横方向の数
   rect_num : Integer;
   //ループカウンタ
   x,y : Integer;
begin
   //引数imgの幅を取得
   img_w := img.Picture.Bitmap.Width;

   //ブロックの幅の初期値を設定
   rect_w := 20;

   //ブロックの幅がimgの幅以下である限り繰り返す
   while rect_w <= img_w do
   begin

      //ブロックの高さを算出
      rect_h := rect_w * 3 div 4;

      //塗りつぶすブロックの数を取得
      //縦、横方向で同じ数となる
      rect_num := img_w div rect_w;

      //横方向のブロックについて繰り返す
      for y := 0 to rect_num - 1 do
         //縦方向のブロックについて繰り返す
         for x := 0 to rect_num - 1 do
         begin
            //ブロックの一番左上のピクセルの色を得て、
            //imgの塗りつぶし色に設定する
            img.Picture.Bitmap.Canvas.Brush.Color :=
               GetPixel(img.Picture.Bitmap.Canvas.Handle,
                        rect_w*x,rect_h*y);

            //ブロックを塗りつぶす
            img.Picture.Bitmap.Canvas.FillRect(
               Rect(rect_w*x,rect_h*y,
                    rect_w*(x+1),rect_h*(y+1)));
         end;

      //画面全体の処理が終わったら、再描画する
      img.Repaint;

      //処理が速すぎる為、ウェイトを置く
      Sleep(50);

      //ブロックの幅を2倍にする
      rect_w := rect_w * 2;
   end;
end;

//背景のモザイクイン
//裏画面(backbmp)から背景を転送した後モザイクをかける
procedure TEffect.MosaicIn(img : TImage; backbmp : TBitmap);
var
   //引数imgの幅
   img_w : Integer;
   //塗りつぶすブロックの幅および高さ
   rect_w,rect_h : Integer;
   //塗りつぶすブロックの縦または横方向の数
   rect_num : Integer;
   //ループカウンタ
   x,y : Integer;
begin
   //引数imgの幅を取得
   img_w := img.Picture.Bitmap.Width;

   //ブロックの幅の初期値を設定
   rect_w := img_w;

   //ブロックの幅が20ピクセル以上である限り繰り返す
   while rect_w >= 20 do
   begin
      //裏画面から表画面に背景を転送
      img.Picture.Assign(backbmp);

      //ブロックの高さを算出
      rect_h := rect_w * 3 div 4;

      //塗りつぶすブロックの数を取得
      //縦、横方向で同じ数となる
      rect_num := img_w div rect_w;

      //横方向のブロックについて繰り返す
      for y:=0 to rect_num-1 do

         //縦方向のブロックについて繰り返す
         for x:=0 to rect_num-1 do
         begin
            //ブロックの一番左上のピクセルの色を得て、
            //imgの塗りつぶし色に設定する
            img.Picture.Bitmap.Canvas.Brush.Color :=
               GetPixel(img.Picture.Bitmap.Canvas.Handle,
                        rect_w*x,rect_h*y);

            //ブロックを塗りつぶす
            img.Picture.Bitmap.Canvas.FillRect(
               Rect(rect_w*x,rect_h*y,
                    rect_w*(x+1),rect_h*(y+1)));
         end;

      //画面全体の処理が終わったら、再描画する
      img.Repaint;

      //処理が速すぎる為、ウェイトを置く
      Sleep(50);

      //ブロックの幅を半分にする
      rect_w := rect_w div 2;
   end;

   //最後に裏画面から表画面に背景を転送
   img.Picture.Assign(backbmp);
   //再描画する
   img.Repaint;
end;
            

            
//背景ＣＧを変更する手続き
//BGNumber : 背景ＣＧの番号
//EffectType : 変更エフェクト
procedure TMainForm.ChangeBackGround(EffectType : string; BGNumber : Integer);
var
   //TEffectクラスのインスタンス変数
   ef : TEffect;
begin
   //背景ＣＧの番号を設定する
   CurBack := BGNumber;
   //指定された番号の背景ＣＧをロードする
   BackBmp.LoadFromFile(Format('..\\..\\data\\bg%.2d.bmp',[CurBack]));

   //TEffectクラスの実体を生成する
   ef := TEffect.Create;
   try
      //EffectTypeによる分岐
      //'black'の場合、ブラックアウト→ブラックイン
      if EffectType = 'black' then
      begin
         ef.BlackOut(PrimImage);
         ef.BlackIn(PrimImage,BackBmp);
            
            
      end
      //'mosaic'の場合、モザイクアウト→モザイクイン
      else if EffectType = 'mosaic' then
      begin
         ef.MosaicOut(PrimImage);
         ef.MosaicIn(PrimImage,BackBmp);
            
            
      end;
   finally
      //オブジェクトを解放する
      ef.Free;
   end;

   //立ち絵は消去されているためフラグを降ろす
   SetChara := False
end;
            

            
//「ロード」メニューが押された時のイベント
procedure TMainForm.MnuLoadClick(Sender: TObject);
（中略）
   ChoiceNum := loaddata.ChoiceNum;

   //セーブした状態を復元する
            
            
   //背景CGの変更
   ChangeBackGround('mosaic',CurBack);
            
            
   SetChara := loaddata.SetChara;
   if SetChara then DrawChara;
   DrawMessageWindow;
   PutText(TextPoint);
   CDPlay(CurTrack);
   if phase = choice then ChoiceInit;

end;